Правильная индикация прогресса цикла на клиенте

Публикация № 57223

Разработка - Практика программирования

индикатор прогрессор прогресс

171
Работу некоторых циклов с большим количеством проходов разумно сопровождать индикацией прогресса. Но зачастую сама эта индикация и становится главным тормозом процесса. Так как частенько на практике встречаю подобные огрехи, решил опубликовать пример правильной индикации. Речь идет про выполнение кода на клиенте.
Так как индикатор представляет собой элемент графического интерфейса пользователя, то любая операция с ним выполняется относительно долго, будь то строка состояния, индикатор или даже надпись. Поэтому в случае большого количества проходов цикла обновление индикатора на каждом проходе может стать главным потребителем вычислительных ресурсов компьютера. Хотя такие ситуации легко обнаруживаются с помощью замера производительности, все же лучше сразу предусматривать подобные проблемы.
 
Привожу 2 вспомогательных метода, которые позволят просто и эффективно реализовать индикацию любого цикла.
// Получает структуру для индикации прогресса цикла. 
// 
// Параметры: 
// КоличествоПроходов – Число - максимальное значение счетчика; 
// ПредставлениеПроцесса – Строка, "Выполнено" – отображаемое название процесса; 
// ВнутреннийСчетчик - Булево, *Истина - использовать внутренний счетчик с начальным значением 1, 
// иначе нужно будет передавать значение счетчика при каждом вызове обновления индикатора; 
// КоличествоОбновлений - Число, *100 - всего количество обновлений индикатора; 
// ЛиВыводитьВремя - Булево, *Истина - выводить приблизительное время до окончания процесса; 
// РазрешитьПрерывание - Булево, *Истина - разрешает пользователю прерывать процесс. 
// МинимальныйПериодОбновления - Число, *1 - с, обновлять не чаще чем этот период, 0 - по количеству обновлений, 
// эта реализация не поддерживает дробные значения; 
// 
// Возвращаемое значение: 
// Структура - которую потом нужно будет передавать в метод ЛксОбработатьИндикатор. 
// 
Функция ЛксПолучитьИндикаторПроцесса(Знач КоличествоПроходов = 0, ПредставлениеПроцесса = "Выполнение", ВнутреннийСчетчик = Истина, Знач КоличествоОбновлений = 100, ЛиВыводитьВремя = Истина, РазрешитьПрерывание = Истина, МинимальныйПериодОбновления = 1) Экспорт
	Индикатор = Новый Структура;
	Если КоличествоПроходов = 0 Тогда
		Состояние(ПредставлениеПроцесса + "...");
		КоличествоПроходов = 1;
	КонецЕсли;
	Индикатор.Вставить("КоличествоПроходов", КоличествоПроходов);
	Индикатор.Вставить("ПредставлениеПроцесса", ПредставлениеПроцесса);
	Индикатор.Вставить("ЛиВыводитьВремя", ЛиВыводитьВремя);
	Индикатор.Вставить("РазрешитьПрерывание", РазрешитьПрерывание);
	Индикатор.Вставить("ДатаНачалаПроцесса", ТекущаяДата());
	Индикатор.Вставить("МинимальныйПериодОбновления", МинимальныйПериодОбновления);
	Индикатор.Вставить("ДатаСледующегоОбновления", Дата('00010101'));
	Индикатор.Вставить("ВнутреннийСчетчик", ВнутреннийСчетчик);
	Если КоличествоОбновлений > 0 Тогда 
		Шаг = КоличествоПроходов / КоличествоОбновлений;
	Иначе 
		Шаг = 0; 
	КонецЕсли; 
	Индикатор.Вставить("Шаг", Шаг); 
	Индикатор.Вставить("СледующийСчетчик", 0); 
	Индикатор.Вставить("Счетчик", 0); 
	Возврат Индикатор; 
КонецФункции

// Проверяет и обновляет индикатор. Нужно вызывать на каждом проходе индицируемого цикла. 
// 
// Параметры: 
// Индикатор – Структура – индикатора, полученная методом ЛксПолучитьИндикаторПроцесса; 
// Счетчик – Число – внешний счетчик цикла, используется при ВнутреннийСчетчик = Ложь. 
// 
Процедура ЛксОбработатьИндикатор(Индикатор, Счетчик = 0) Экспорт
	Если Индикатор.ВнутреннийСчетчик Тогда 
		Счетчик = Индикатор.Счетчик + 1;
		Индикатор.Счетчик = Счетчик;
	КонецЕсли; 
	Если Индикатор.РазрешитьПрерывание Тогда
		ОбработкаПрерыванияПользователя();
	КонецЕсли; 
	ОбновитьИндикатор = Истина;
	ТекущаяДата = ТекущаяДата();
	Если Индикатор.МинимальныйПериодОбновления > 0 Тогда
		Если ТекущаяДата < Индикатор.ДатаСледующегоОбновления Тогда
			ОбновитьИндикатор = Ложь;
		КонецЕсли; 
	КонецЕсли;
	Если ОбновитьИндикатор Тогда
		Если Индикатор.Шаг > 0 Тогда
			Если Счетчик >= Индикатор.СледующийСчетчик Тогда
				Индикатор.СледующийСчетчик = Цел(Счетчик + Индикатор.Шаг);
			Иначе
				ОбновитьИндикатор = Ложь;
			КонецЕсли; 
		КонецЕсли; 
	КонецЕсли; 
	Если ОбновитьИндикатор Тогда
		Индикатор.СледующийСчетчик = Цел(Счетчик + Индикатор.Шаг); 
		Если Индикатор.ЛиВыводитьВремя Тогда 
			ПрошлоВремени = ТекущаяДата - Индикатор.ДатаНачалаПроцесса; 
                        Осталось = ПрошлоВремени * (Индикатор.КоличествоПроходов / Счетчик - 1);
                        ОсталосьДней = Цел(Осталось / (24*60*60));
                        ТекстОсталось = ", Осталось: ";
                        Если ОсталосьДней > 0 Тогда
                            ТекстОсталось = ТекстОсталось + ОсталосьДней + "д";
                        КонецЕсли;
                        ТекстОсталось = ТекстОсталось + Формат(Дата(1,1,1) + Осталось, "ДЛФ=T");
			ТекстОсталось = "Осталось: " + ТекстОсталось + ?(Индикатор.РазрешитьПрерывание, ".  Прервать: Ctrl+Break", ""); 
		Иначе
			ТекстОсталось = ""; 
		КонецЕсли; 
		ТекстСостояния = Индикатор.ПредставлениеПроцесса + " " + Формат(Счетчик / Индикатор.КоличествоПроходов * 100, "ЧЦ=3; ЧДЦ=0") + "% " + ТекстОсталось; 
		Состояние(ТекстСостояния); 
	КонецЕсли; 
	Если Счетчик = Индикатор.КоличествоПроходов Тогда 
		Состояние(""); 
	КонецЕсли;
КонецПроцедуры

Ключевым моментом в ЛксОбработатьИндикатор() для обновления состояния является требование выполнения

в общем случае двух (любое можно отключить) условий:
- прошло минимальное время с момента последнего обновления

- не превысить заданное общее число обновлений

Вот пример их использования.

КоличествоДанных = 100000;
Индикатор = ЛксПолучитьИндикаторПроцесса(КоличествоДанных, "Проверка данных");
Для Счетчик = 1 По КоличествоДанных Цикл 
	ЛксОбработатьИндикатор(Индикатор, Счетчик);
КонецЦикла;
КоличествоДанных = 100000;
Индикатор = ЛксПолучитьИндикаторПроцесса(КоличествоДанных, "Проверка данных", Истина);
Для Счетчик = 1 По КоличествоДанных Цикл  
	ЛксОбработатьИндикатор(Индикатор);
КонецЦикла;

 
171

Специальные предложения

Комментарии
Избранное Подписка Сортировка: Древо
1. alexqc 13.08.08 17:30 Сейчас в теме
Все хорошо, только умножение-деление на каждом шаге - тоже затратная операция. Конечно, не настолько как перерисовка, но всеж можно еще чуть-чуть убыстрить:

Код
 
Счетчик=0;
СледСчетчик=0;
ОдинПроцент=КвоЭлементов/100;
Пока ..... цикл

   Счетчик=Счетчик+1;
   Если Счетчик>СледСчетчик Тогда
       СледСчетчик=Цел(Счетчик+ОдинПроцент);
      Состояние("Выполнено "+Цел(Счетчик/ОдинПроцент)+"%");
   КонецЕсли;

КонецЦикла;
Показать полностью


А вообще, ИМХО, лучше считать не по 1%, а по 5%-10%. Или блоками по 50-10-5 записей (в зависимости от того сколько осталось). А то наблюдать проценты, бегущие по одному - тоже невесело.
Pavl0; wowik; ybatiaev; jobkostya1c8; tormozit; Kino; +6 Ответить
2. tormozit 5592 13.08.08 17:45 Сейчас в теме
(1) Спасибо. Твой вариант конечно же более красивый и эффективный. Берем на вооружение.
3. tormozit 5592 17.10.08 12:07 Сейчас в теме
Оптимизировал и немного расширил возможности
4. alexk-is 6421 27.10.08 20:09 Сейчас в теме
Если выжимать "соки", тогда уж так, наверное...

Код
Счетчик=0;
СледСчетчик=0;
ОдинПроцент = КвоЭлементов * 0.01; // ---
Коэффициент = 100 / КвоЭлементов; // ---
Пока ..... цикл

   Счетчик=Счетчик+1;
   Если Счетчик>СледСчетчик Тогда
      СледСчетчик=Цел(Счетчик+ОдинПроцент);
      Состояние("Выполнено "+Цел(Счетчик * Коэффициент)+"%"); // ---
   КонецЕсли;

КонецЦикла;
Показать полностью
ybatiaev; romankoav; +2 Ответить
5. O-Planet 6974 27.10.08 20:20 Сейчас в теме
Просмотрел... Не понравился момент Счетчик/Шаг. А вообще, алгоритм не оптимальный. В (4) мне нравится больше. Зачетно было бы вообще освободиться от умножения и деления в цикле.

Код
Шаг = Количество / 100;
ТекШаг=Шаг;
К=1;
Процент=0;
Пока ... Цикл
  К=К+1;
  Если К>=ТекШаг Тогда
    Процент=Процент+1;
    ТекШаг=ТекШаг+Шаг;
    Сообщить("Выполнено "+Процент+" % ...");
  КонецЕсли;
  ...
КонецЦикла;
Показать полностью

6. tormozit 5592 27.10.08 20:51 Сейчас в теме
(5) Каждому свое. Для меня например немаловажную роль играет количество строк в конструкции. Разница в производительности между нашими вариантами будет незначительной даже при холостом прогоне, а уж при нагрузочном прогоне она почти исчезент. А вот у меня на 2 строки меньше получается конструкция. Вообще, на ассме я тоже писал и тоже могу оптимизировать код, но кажется здесь не тот случай.
Основная идея публикации от тебя видимо ускользнула через призму (4) =)
7. alexk-is 6421 27.10.08 21:05 Сейчас в теме
(5) У меня тоже был такой "очевидный" вариант. Но как оказалось - работает медленнее... Думаю это проблема интерпретаторов, когда две "сложные" команды обрабатываются быстрее, чем три простые...
8. tormozit 5592 27.10.08 21:19 Сейчас в теме
(7) А может быть это не проблема, а благо?)
17. alexqc 146 15.12.08 11:22 Сейчас в теме
(4) согласен (хотя лично я не люблю обратных величин). А вобще, жалко что в 1С нету _целочисленного_ умножения/деления.

На самом деле, оптимизнуть можно в СледСчетчик=Цел(Счетчик+ОдинПроцент) от Цел() избавившись. Т.к. Счетчик у нас итак целый, значит дробь м.б. только от ОдинПроцент. Потому мы спокойно можем сделать ему Цел() вне цикла.


(5) Что ж там неоптимально??? деление выполнется не более 100 раз, это много?
И выполняется оно исключительно в целях более точной индикации.

Ваш же код неверен - для примера, представьте индикацию, когда кол-во шагов будет меньше 100.

(9) А тут код действительно неоптимальный. Мы выполняем "%" (что есть эквивалент "/" ) на _каждом_ шаге - как раз то, от чего пытались уйти.
18. O-Planet 6974 15.12.08 12:15 Сейчас в теме
(17) Решается простой проверкой
19. Evg-Lylyk 2678 15.12.08 15:05 Сейчас в теме
(17) по поводу ответа на (9). Я честно не пробовал, но думаю что на интерпретаторе деление будет еще и быстрее чем замена или разница не ощутима (да еще и минус одна переменная и наглядность). Я там кстати забыл функцию Цел() Цел(Счетчик % Шаг)=0

На мой взгляд лучше индикация раз в секунду:
там где проверка выводить индикацию проверяем сменилась ли секунда.
Сделал так когда столкнулся с необходимости выводить время прошедшее и оставшееся. Некрасиво получается когда процесс выполняется очень быстро меньше 5 секунд. Зато влияние индикации стало минимальным.
20. Evg-Lylyk 2678 15.12.08 15:17 Сейчас в теме
(17) провирил скорость на примере
1. 55,4% времени
Для Сч=1 По 10000 Цикл
А=Сч %100;
КонецЦикла;
2.45,4 % времени
Для Сч=1 По 10000 Цикл
А=Сч + 212;
КонецЦикла;
разница мала
22. Evg-Lylyk 2678 22.12.08 23:15 Сейчас в теме
(21) Люди там старались убрать операцию деления т.к. она вроде как долго.
9. Evg-Lylyk 2678 13.12.08 11:24 Сейчас в теме
Можно проще и нагляднее. Есть операция остаток от деления "%". Пример 10%3=1. Пример кода:

ПредставлениеПроцесса = "Обработка строк таблицы";
Счетчик = 0;// СледующийСчетчик = 0;
Шаг = Таблица.Количество() / 100;
Для Каждого Строка Из Таблица Цикл
ОбработкаПрерыванияПользователя();
Счетчик = Счетчик + 1;
//Если Счетчик > СледующийСчетчик Тогда
Если Счетчик % Шаг=0 Тогда
//СледующийСчетчик = Цел(Счетчик + Шаг);
Состояние(ПредставлениеПроцесса + " " + Формат(Счетчик / Шаг, "ЧЦ=3; ЧДЦ=0") + "%");
КонецЕсли;

КонецЦикла;
10. tormozit 5592 14.12.08 12:46 Сейчас в теме
Обновил. Теперь все стало намного красивее и удобнее.
14. tormozit 5592 14.12.08 19:43 Сейчас в теме
(13) Если плясать от плотности по времени, то это совсем другой подход. Мой подход в большинстве случаев ест заранее известное количество вычислительных ресурсов.

(11) Формы обычно не нужны. Это красиво, но надо объект метаданных задействовать.
16. tormozit 5592 14.12.08 20:05 Сейчас в теме
Я про фиксированную плотность по времени раньше тебя придумал))))) Но делать не стал, т.к. пока нет необходимости. Не отрицаю, что это будет полезно.
24. zzerro 276 27.04.09 13:54 Сейчас в теме
Расчет времени выполнения и все такое эт канечно красиво... Но я для своих обработок сделал такое и особо не парюсь...

Процедура глОбработкаИндикатора(ТекСчетчик,ТекИндикатор,ЧастотаОбновления) Экспорт
// ТекСчетчик - перемнная счетчика цикла (в теле цикла увеличивать ее не надо)
// ТекИндикатор - Переменная связанная с элементом формы Индикатор
// ЧастотаОбновления - частота обновления индикатора в количестве раз обхода цикла

// Увеличим индикатор цикла
ТекСчетчик = ТекСчетчик + 1;
Если ТекСчетчик >= ЧастотаОбновления Тогда
ТекИндикатор = ТекИндикатор + ТекСчетчик;
ТекСчетчик = 0;
КонецЕсли;
КонецПроцедуры

В цикле вызывается эта процедура и индикатор изменяется столько сколько мне надо.

Например так
Сч = 0;
Индикатор = 0;
ЧастотаОбновления = ТЗ.Количество() * 0.1; // т.е. каждые 10% данных
Для каждого Стр из ТЗ Цикл
<что там надо нам сделать>
глОбработкаИндикатора(Сч,Индикатор,ЧастотаОбновления);
КонецЦикла;
25. zzerro 276 27.04.09 13:56 Сейчас в теме
Мелкие погрешности канечно есть, но это абсолютно не важно
26. zzerro 276 27.04.09 13:58 Сейчас в теме
забыл написать еще, что перед циклом:
ЭлементыФормы.Индикатор.МаксимальноеЗначение = ТЗ.Количество();
27. Mitay 06.02.10 18:56 Сейчас в теме
еще можно добавить что-то типа
Функция лксТекстИндикатора(Индикатор)
		возврат Индикатор.ПредставлениеПроцесса + " " 
			+ Формат(Индикатор.Счетчик / Индикатор.КоличествоПроходов * 100, "ЧЦ=3; ЧДЦ=0") + "%   ";
КонецФункции // лксТекстИндикатора()

тогда индикатор вложенного цикла будет
Индикатор = ЛксПолучитьИндикаторПроцесса(тзСсылок.Количество(),  лксТекстИндикатора(ИндикаторОбщий) + "  вложенный цикл:");
28. tormozit 5592 19.04.10 13:40 Сейчас в теме
Добавил поддержку минимального периода обновления
29. i_lo 198 07.12.10 01:21 Сейчас в теме
А как вывести индикатор для процесса, который идет на сервере и "каждую секунду" показывает на экране состояние, не возвращаясь в вызвавшую процедуру? Или это тоже, как фоновое задание?
30. simol 21.02.11 14:37 Сейчас в теме
Имеет смысл уточнить, что ЛксОбработатьИндикатор вставлять нужно перед концом цикла
31. RFRDCT 20.11.11 17:44 Сейчас в теме
AlexQC пишет:

Все хорошо, только умножение-деление на каждом шаге - тоже затратная операция. Конечно, не настолько как перерисовка, но всеж можно еще чуть-чуть убыстрить:





http://infostart.ru/public/65665/
32. nitr02k 06.12.11 15:19 Сейчас в теме
Занятно очень пригодиться
33. decdmb 19.03.12 13:37 Сейчас в теме
Тоже использовал что-то похожее у себя (по проще конечно), раньше не замечал (на 13 платформе), но сейчас при выполнении какого-нибудь большого цикла, вывод прогресса зависает, хотя сам цикл выполняется 100%. Пробовал и с данными функциями - тоже самое. Платформа 8.2.15.301.
34. tormozit 5592 19.03.12 14:09 Сейчас в теме
(33) Скорее всего проблема в твоем коде.
35. decdmb 19.03.12 15:42 Сейчас в теме
(34) Использовал и ваши функции:
	КолВо = 500000;	
	i = 0;	
	Индикатор = ЛксПолучитьИндикаторПроцесса(КолВо, "Прогресс", Истина, 100, Истина, Истина, 1);	
	Пока i < КолВо Цикл
		ЛксОбработатьИндикатор(Индикатор);
		i = i + 1;
	КонецЦикла;
Показать

При потере фокуса, и обратном переключении индикация не обновляется
36. tormozit 5592 19.03.12 16:10 Сейчас в теме
(35) Есть ряд особенностей платформы, которые заставляют считать такое поведение нормой. Например, выполнение этого кода в обработчике ожидания. Только что проверил на 8.2.15.301 обычное приложение файловая СУБД - описанная тобой проблема не воспроизводится при обычном выполнении кода.
37. decdmb 21.03.12 11:50 Сейчас в теме
(36) Вроде разобрался. Косяк с остановкой индикации возникает при вызове функции(содержащей индикацию прогресса цикла)в модуле объекта внешней обработки. Если эту функцию вызывать в модуле формы, то все норм
38. tormozit 5592 21.03.12 12:15 Сейчас в теме
(37) Можешь выложить пример, демонстрирующий проблему?
39. decdmb 21.03.12 12:41 Сейчас в теме
Тест При открытии обработки запускается процедура из модуля объекта (при потере фокуса индикация зависает), а при нажатии на Выполнить вызывается та же процедура, но прогресс не виснет при потере фокуса
40. tormozit 5592 22.03.12 00:52 Сейчас в теме
(39) Действительно, при долгом выполнении кода в разделе инициализации модуля окно перестает перерисовываться. Я постоянно сражаюсь за исправление подобного рода неудобств в платформе, но иногда ошибкой такой поведение 1С признавать не хотят. Кажется с разделом инициализации модуля так и было. Попробую еще разок им написать для верности.
41. candy_sk 17.04.12 15:32 Сейчас в теме
Вот как! Со времен семерки такое искал, а тут сделали на новой платформе - молодцы!
42. Жолтокнижниг 248 03.06.12 23:07 Сейчас в теме
За идею +. А код нужно оптимизировать, всетаки хочется чтоб второстепенный код потреблял минимум ресурсов.
43. tormozit 5592 03.06.12 23:47 Сейчас в теме
(42) Сколько то заметные операции по умолчанию выполняются 1 раз в секудну. При остальных вызовах там оптимизировать вроде бы нечего. Можете показать замер где видна неоптимальность? Какие есть идеи по оптимизации?
44. Жолтокнижниг 248 04.06.12 13:32 Сейчас в теме
(43) использовать возврат вместо флага "ОбновитьИндикатор" вычисление времени через дата(1,1,1)+осталось и форматный вывод,ускорило в 2-3 раза, + сокращение строк кода, не замерял но тоже даст прирост
tormozit; +1 Ответить
45. tormozit 5592 04.06.12 14:24 Сейчас в теме
(44) Спасибо. Формирование строки состояния через Формат действительно лучше выполнять. Остальное считаю неразумной экономией ("на спичках").
46. DoctorRoza 24.11.12 10:24 Сейчас в теме
47. _n26__ 08.01.13 21:23 Сейчас в теме
Спасибо, очень пригодиться!
48. CaSH_2004 354 06.03.13 21:59 Сейчас в теме
Отличная вещь, сам делал да терпения не хватило вылизать, так что к себе в ГОСиД вставил
но чуток поправил:
1. вместо:
    Если КоличествоОбновлений > 0 Тогда
        Шаг = КоличествоПроходов / КоличествоОбновлений;
    Иначе
        Шаг = 0;
    КонецЕсли;
    Индикатор.Вставить("Шаг", Шаг);

упростил:
Индикатор.Вставить("Шаг", ?(КоличествоОбновлений > 0, КоличествоПроходов / КоличествоОбновлений, 0));

2. вместо:
ТекстОсталось = "Осталось примерно: " + ОсталосьВремени;

уточнил (а то не все в курсе особенно 7-ки, да и в любом случае полезно):
ТекстОсталось = "Осталось примерно: " + ОсталосьВремени + ?(Индикатор.РазрешитьПрерывание, "    Прервать: Ctrl+Pause/Break", "");

3. и добавил для визуализации в ЛксПолучитьИндикаторПроцесса переменную Прогресс, куда передаю элемент формы чтобы видеть ползунок если он есть на форме
		Если Индикатор.Прогресс <> Неопределено Тогда 
			Индикатор.Прогресс.Значение = Счетчик;
		КонецЕсли;

4. не совсем понял зачем ВнутреннийСчетчик, можно расшифровать?
5. совсем не понял зачем в конце ЛксОбработатьИндикатор() проверка
Если ТипЗнч(Индикатор) = Тип("СтрокаТаблицыЗначений") Тогда

ведь в описании это Структура, и в начале процедуры к ней обращаются как к структуре и если передать строку то получим ошибку:
Если Индикатор.ВнутреннийСчетчик Тогда

Я так понимаю что строку нужно либо передавать отдельным параметром (завести новый) либо вообще это отдельный случай (аппендикс походу :)
Я такое как-то делал но проверку на любую коллекцию Массив, Структура, и остальные
tormozit; +1 Ответить
49. tormozit 5592 07.03.13 02:10 Сейчас в теме
(48)
1. Действительно твой вариант будет несколько быстрее, но я не люблю экономить на копейках, снижая отлаживаемость кода.
2. Тоже пару раз хотел добавить, но пересиливал себя =)
- много лишнего текста будет отвлекать от главного
- текст справа от переменного фрагмента будет прыгать (смещаться) вправо-влево, что привлекает лишнее внимание
- усложнится многоуровневый индикатор (здесь не представлен)
3. У строки состояния перед формой весомое приемущество - ее практически не нужно очищать/убирать/закрывать в случае прерывания процесса исключением или пользователем.
4. Не понял вопроса, можешь пояснить?
5. Индикатор типа СтрокаТаблицыЗначений используется в многоуровневом индикаторе (здесь не представлен)
50. CaSH_2004 354 07.03.13 02:38 Сейчас в теме
(49)1. Странно как он влияет на отладку, вроде очевидная вещь, чего ее отлаживать? Получается конструкцией ?(,,) вообще не пользуешся?
2.
- Ну кому как, мне так наоборот красивше, к тому же реально полезно, а не просто так
- Ну смещение то будет незначительное, только на 1 символ и только 9 раз, смотри:
Выполнено 1% Осталось: 00:01:00 Прервать: Ctrl+Pause/Break (от 1 до 9)
и
Выполнено 10% Осталось: 00:01:00 Прервать: Ctrl+Pause/Break ( а тут все остальное)
- вот насчет многоуровневого не в курсе, если его тут нет то что на него равнятся то?
3. Естественно, однако я часто запускаю процесс и ухожу еще куда-нибудь по делам, издалека хорошо видно статус, а вот текст в строке состояния, так что мне и подходить не нужно чтобы понять сколько выполнилось, а чтобы уточнить можно и приглядеться
4. Ну переменная у тебя есть такая
ВнутреннийСчетчик - Булево, *Истина - использовать внутренний счетчик с начальным значением 1, иначе нужно будет передавать значение счетчика при каждом вызове обновления индикатора;

Это наверно когда делается несколько итераций прежде чем вызывается твоя функция? Но мне сложно представить такую потребность
5. Опять же - если его нет то зачем код от него тут? На него же тратится время и вообще он мусорный или как?
51. tormozit 5592 07.03.13 09:26 Сейчас в теме
1-3 Это все довольно очевидно. Дело вкуса.
4. Приведи пример использования индикатора для этого вопроса. Похоже я все еще не понимаю.

Про многоуровневый индикатор я пишу потому, что у меня он есть и я не хочу держать по несколько версий одной функции. Вношу исправление в одну и сразу можно публиковать ее сюда без дополнительных телодвижений.
52. Glebis 11 11.09.15 10:08 Сейчас в теме
Простите за некропостинг, но вот все-таки не понял:
1) А зачем в процедуре дважды обновляется
ТекущаяДата = ТекущаяДата(); 
с разрывом в несколько строк. Если бы 1ое объявление было под условием, а второе безусловное, то я бы понял, но в коде то наоборот... Да и вообще после объявления переменной "ТекущаяДата" она может и не понадобится, если не выполнится ни одно из условий ниже. А процедуру ТекущаяДата() желательно заменять на ТекущаяДатаСеанса(), так написано в желтой библии;

2) Зачем задублена строка
Индикатор.СледующийСчетчик = Цел(Счетчик + Индикатор.Шаг);
, если она выполняется при одинаковом условии ОбновитьИндикатор = Истина?

3) Зачем проверяется тип входящего параметра
Если ТипЗнч(Индикатор) = Тип("СтрокаТаблицыЗначений")
, если он всегда будет с типом структура? Как я понял этот блок для вызова процедуры для многоуровневой индикации. Почему коммент нельзя было оставить?

4) Что за извращение?
						Часов = Цел(Осталось / 3600); 
						Осталось = Осталось - (Часов * 3600);
						Минут = Цел(Осталось / 60);
						Секунд = Цел(Цел(Осталось - (Минут * 60)));
						ОсталосьВремени = Формат(Часов, "ЧЦ=2; ЧН=00; ЧВН=") + ":" + Формат(Минут, "ЧЦ=2; ЧН=00; ЧВН=") 
						+ ":" + Формат(Секунд, "ЧЦ=2; ЧН=00; ЧВН="); 
Процессорное время лишнее? Почему не просто:
ОсталосьВремени = Формат(Дата(1,1,1) + Осталось, "ДФ=HH:mm:ss")
Те же лидирующие нули будут...

5) Зачем на последней итерации формировать строку для процедуры Состояние(), если потом все-равно проверяется
Если Счетчик = Индикатор.КоличествоПроходов Тогда 
		Состояние(""); 
КонецЕсли
и устанавливается пустая строка.

6) Зачем при 0ом количестве обновлений занулять шаг и проверять при каждой итерации > 0 или нет. Если достаточно при КоличествоОбновлений = 0 установить СледующийСчетчик = 100 и в итерациях проверять лишь что Счетчик >= Индикатор.СледующийСчетчик.

Не ожидал столько недодумок от столь уважаемого мною разработчика.

Вот оптимизированная (с моей точки зрения) версия этой же процедуры:

// Получает структуру для индикации прогресса цикла. 
// 
// Параметры: 
// КоличествоПроходов – Число - максимальное значение счетчика; 
// ПредставлениеПроцесса – Строка, "Выполнено" – отображаемое название процесса; 
// ВнутреннийСчетчик - Булево, *Истина - использовать внутренний счетчик с начальным значением 1, 
// иначе нужно будет передавать значение счетчика при каждом вызове обновления индикатора; 
// КоличествоОбновлений - Число, *100 - всего количество обновлений индикатора; 
// ЛиВыводитьВремя - Булево, *Истина - выводить приблизительное время до окончания процесса; 
// РазрешитьПрерывание - Булево, *Истина - разрешает пользователю прерывать процесс. 
// МинимальныйПериодОбновления - Число, *1 - с, обновлять не чаще чем этот период, 0 - по количеству обновлений, 
// эта реализация не поддерживает дробные значения; 
// 
// Возвращаемое значение: 
// Структура - которую потом нужно будет передавать в метод ЛксОбработатьИндикатор. 
// 
Функция ЛксПолучитьИндикаторПроцесса(Знач КоличествоПроходов = 0, ПредставлениеПроцесса = "Выполнение", ВнутреннийСчетчик = Истина, Знач КоличествоОбновлений = 100, ЛиВыводитьВремя = Истина, РазрешитьПрерывание = Истина, МинимальныйПериодОбновления = 1) Экспорт
	Индикатор = Новый Структура;
	Если КоличествоПроходов = 0 Тогда
		Состояние(ПредставлениеПроцесса + "...");
		КоличествоПроходов = 1;
	КонецЕсли;
	Индикатор.Вставить("КоличествоПроходов", КоличествоПроходов);
	Индикатор.Вставить("ПредставлениеПроцесса", ПредставлениеПроцесса);
	Индикатор.Вставить("ЛиВыводитьВремя", ЛиВыводитьВремя);
	Индикатор.Вставить("РазрешитьПрерывание", РазрешитьПрерывание);
	Индикатор.Вставить("ДатаНачалаПроцесса", ТекущаяДата());
	Индикатор.Вставить("МинимальныйПериодОбновления", МинимальныйПериодОбновления);
	Индикатор.Вставить("ДатаСледующегоОбновления", Дата('00010101'));
	Индикатор.Вставить("ВнутреннийСчетчик", ВнутреннийСчетчик);
	Если КоличествоОбновлений > 0 Тогда 
		Индикатор.Вставить("Шаг", КоличествоПроходов / КоличествоОбновлений);  ;
		Индикатор.Вставить("СледующийСчетчик", 0); 
	Иначе 
		Индикатор.Вставить("Шаг", 0); 
		Индикатор.Вставить("СледующийСчетчик", 100); 
	КонецЕсли; 
	Индикатор.Вставить("Счетчик", 0); 
	Возврат Индикатор; 
КонецФункции // ЛксПолучитьИндикаторПроцесса() 

// Проверяет и обновляет индикатор. Нужно вызывать на каждом проходе индицируемого цикла. 
// 
// Параметры: 
// Индикатор – Структура – индикатора, полученная методом ЛксПолучитьИндикаторПроцесса; 
// Счетчик – Число – внешний счетчик цикла, используется при ВнутреннийСчетчик = Ложь. 
// 
Процедура ЛксОбработатьИндикатор(Индикатор, Счетчик = 0) Экспорт
	Если Индикатор.ВнутреннийСчетчик Тогда 
		Счетчик = Индикатор.Счетчик + 1;
		Индикатор.Счетчик = Счетчик;
	КонецЕсли; 
	Если Счетчик = Индикатор.КоличествоПроходов Тогда 
		Состояние(); 
	Иначе
		Если Индикатор.РазрешитьПрерывание Тогда
			ОбработкаПрерыванияПользователя();
		КонецЕсли; 
		Если Индикатор.МинимальныйПериодОбновления > 0 Тогда
			ТекущаяДата = ТекущаяДата();
			Если ТекущаяДата >= Индикатор.ДатаСледующегоОбновления Тогда
				Индикатор.ДатаСледующегоОбновления = ТекущаяДата + Индикатор.МинимальныйПериодОбновления;
				Если Счетчик >= Индикатор.СледующийСчетчик Тогда
					Индикатор.СледующийСчетчик = Цел(Счетчик + Индикатор.Шаг);
					Если Индикатор.ЛиВыводитьВремя Тогда 
						Осталось = (ТекущаяДата - Индикатор.ДатаНачалаПроцесса) * (Индикатор.КоличествоПроходов / Счетчик - 1); 
						ТекстОсталось = нСтр("ru='Осталось: ~'", "ru") + Формат(Дата(1,1,1) + Осталось, "ДФ=HH:mm:ss"); 
					Иначе
						ТекстОсталось = ""; 
					КонецЕсли; 
					
					ТекстСостояния = Индикатор.ПредставлениеПроцесса + " " 
					+ Формат(Счетчик / Индикатор.КоличествоПроходов * 100, "ЧЦ=3; ЧДЦ=0") + "% " + ТекстОсталось; 
					
					// Этот блок для многоуровневой индикации.
					//Если ТипЗнч(Индикатор) = Тип("СтрокаТаблицыЗначений") Тогда 
					//	ТаблицаИндикаторов = Индикатор.Владелец();
					//	ИндексИндикатора = ТаблицаИндикаторов.Индекс(Индикатор); 
					//	Если ИндексИндикатора > 0 Тогда 
					//		ТекстСостояния = ТаблицаИндикаторов[ИндексИндикатора - 1].ТекстСостояния + " >> " + ТекстСостояния;
					//	КонецЕсли;
					//	Индикатор.ТекстСостояния = ТекстСостояния; 
					//КонецЕсли; 
					
					Состояние(ТекстСостояния); 
				КонецЕсли; 
			КонецЕсли;
		КонецЕсли
	КонецЕсли;
КонецПроцедуры // ЛксОбработатьИндикатор() 
Показать
tormozit; ShinZeroOne; NeviD; +3 Ответить
53. triviumfan 10 31.08.19 08:23 Сейчас в теме
Как раз хотел "стырить" это с ИР, а тут оказывается, уже давно все выложено:)
Спасибо.
ЗЫ: Сергей, а правда, что отображение индикатора на текущей форме или общей форме хода выполнения заметно затратнее, чем состояние()?
54. triviumfan 10 09.09.19 10:04 Сейчас в теме
Сергей, а можете привести пример, когда тип начения индикатора "СтрокаТаблицыЗначений"?
55. tormozit 5592 09.09.19 10:23 Сейчас в теме
(54) Нет. Его можно увидеть в подсистеме "Инструменты разработчика". В этой статье представлена обрезанная версия для демонстрации основных принципов.
56. triviumfan 10 09.09.19 10:33 Сейчас в теме
(55) Можно хотя бы пояснить, для чего вам таблица состояний индикаторов? Для многопоточных обработок?
57. tormozit 5592 09.09.19 11:03 Сейчас в теме
(56) Нет. Для многоуровненых циклов.
triviumfan; +1 Ответить
58. tormozit 5592 14.09.19 11:23 Сейчас в теме
Оптимизировал код по замечаниям из комментариев. Но эффект от этой оптимизации будет незначительный.
59. mikl79 107 27.09.19 09:20 Сейчас в теме
Добрый день.
Попробовал использовать, но при проверке модуля ругается: Переменная не определена (ОсталосьВремени)
Что за переменная, она нигде не инициализируется?
60. tormozit 5592 27.09.19 09:25 Сейчас в теме
(59) Внес эту ошибку во время последней правки. Исправил.
61. mikl79 107 27.09.19 09:57 Сейчас в теме
(60), спасибо.
Подскажите пожалуйста, проверил если выводить индикацию, то по времени получается раз в 10 дольше (прыгать клиент-сервер-клиент), если совсем не выводить (выполнять все на сервере)
Это из-за прыганья, т.е. выодить индикацию наверное не рекомендуется и тогда в каких случаях можно оправдать вывод индикации?
62. tormozit 5592 27.09.19 11:04 Сейчас в теме
(61) Эта статья написана для выполнения кода на клиенте. Для случая выполнения кода на сервере есть масса других публикаций и способов. Я не планирую расширять статью на этот случай.
63. evgen7938 7 27.09.19 16:05 Сейчас в теме
Сергей, подскажите пож-та, что означает "Лкс" в названии процедуры/функции (например: ЛксПолучитьИндикаторПроцесса)?
64. tormozit 5592 27.09.19 16:14 Сейчас в теме
(63) Это - префикс. Другого значения у этой строки нет.
65. evgen7938 7 27.09.19 16:22 Сейчас в теме
(64) Этот префикс - он ведь не во всех методах присутствует (речь про ИР)? Подскажите пож-та, при изучении кода ИР мне следует придавать этому префиксу какое-либо значение?
66. tormozit 5592 27.09.19 21:13 Сейчас в теме
Оставьте свое сообщение

См. также

Агрегатные функции СКД, о которых мало кто знает 315

Статья Программист Нет файла v8 v8::СКД 1cv8.cf Бесплатно (free) Практика программирования

Пользуетесь ли Вы всеми возможными агрегатными функциями, которые предоставляет система компоновки данных? Если Вы используете только: СУММА, КОЛИЧЕСТВО, МИНИМУМ, МАКСИМУМ, СРЕДНЕЕ, то эта статья для Вас.

05.09.2019    9686    ids79    42       

Три костыля. Сказ про фокусы в коде 121

Статья Программист Нет файла v8 Бесплатно (free) Практика программирования Разработка

Три интересных (или странных) костыля в коде, которые могут помочь в повседневных и не очень задачах.

03.09.2019    7653    YPermitin    67       

Отслеживание выполнения фонового задания 133

Статья Программист Нет файла v8 1cv8.cf Бесплатно (free) Практика программирования Универсальные функции Разработка

Запуск фонового задания из модуля внешней обработки. Отслеживание выполнения задания в виде прогресса, расположенного на форме.

17.08.2019    8036    ids79    14       

Функции СКД: ВычислитьВыражение, ВычислитьВыражениеСГруппировкойМассив 240

Статья Программист Нет файла v8 v8::СКД 1cv8.cf Бесплатно (free) Практика программирования

Подробное описание и использование внутренних функций системы компоновки данных: Вычислить, ВычислитьВыражение, ВычислитьВыражениеСГруппировкойМассив, ВычислитьВыражениеСГруппировкойТаблицаЗначений.

08.08.2019    10076    ids79    22       

Фоновое выполнение кода в 1С - это просто 117

Статья Программист Нет файла v8 1cv8.cf Бесплатно (free) Практика программирования Разработка

Как легко запускать выполнение в фоне, не прибегая к долгому описанию фоновых процедур.

02.08.2019    9670    avalakh    21       

СКД - наборы данных и связи между ними, создание собственной иерархии, вложенные отчеты 126

Статья Программист Нет файла v8 v8::СКД 1cv8.cf Бесплатно (free) Практика программирования Разработка

Набор данных объект. Использование в схеме компоновки нескольких наборов данных. Различные варианты связи наборов: объединение, соединение. Использование иерархии в отчетах на СКД. Создание собственной иерархии, иерархия детальных записей. Использование вложенных схем в отчетах на СКД.

26.07.2019    9051    ids79    6       

СКД - использование расширений языка запросов, секция ХАРАКТЕРИСТИКИ 134

Статья Программист Нет файла v8 v8::СКД Бесплатно (free) Инструментарий разработчика Практика программирования Разработка

Автоматическое и не автоматическое заполнение полей компоновки данных. Использование расширений языка запросов для СКД «{…}», секция ВЫБРАТЬ, секция ГДЕ, параметры виртуальных таблиц. Автоматизированное использование дополнительных данных в запросе: секция ХАРАКТЕРИСТИКИ.

17.07.2019    8521    ids79    24       

"Меньше копипаста!", или как Вася универсальную процедуру писал 170

Статья Программист Стажер Нет файла v8 v8::СКД 1cv8.cf Бесплатно (free) Практика программирования Разработка

Программист Вася разбирает подход создания универсальных методов на примере программного вывода СКД.

04.07.2019    6144    SeiOkami    48       

Создание отчетов с помощью СКД - основные понятия и элементы 190

Статья Программист Нет файла v8 v8::СКД Бесплатно (free) Практика программирования Математика и алгоритмы

Основные принципы работы СКД. Понятия схемы компоновки и макета компоновки. Описание основных элементов схемы компоновки: наборы данных, поля, вычисляемые поля, ресурсы, параметры.

25.06.2019    17171    ids79    16       

Многопоточное ускорение однопользовательских нагрузок в 1С + Microsoft SQL Server 2017 176

Статья Программист Нет файла v8 v8::Запросы Бесплатно (free) Практика программирования Разработка

Взаимодействие с Microsoft SQL Server нередко вызывает трудности у 1С-ников, а потому интересны любые моменты, связанные с его использованием. О своем опыте работы с новым SQL Server 2017 участникам конференции Infostart-2018 рассказал директор ООО «Аналитика софт» Дмитрий Дудин.

11.06.2019    11414    dmurk    134       

Регистры накопления. Структура хранения в базе данных 174

Статья Программист Нет файла v8 1cv8.cf Бесплатно (free) Практика программирования Разработка

Структура хранения регистров накопления в базе данных для платформы 1С:Предприятие 8.x. Первая часть в серии публикаций.

16.05.2019    17079    YPermitin    27       

Выполнение внешней обработки в фоновом задании 147

Статья Программист Нет файла v8 1cv8.cf Бесплатно (free) Практика программирования Разработка

Подробное описание подхода к созданию длительной операции на основе внешней обработки. Реализация протестирована на 1С 8.3.12.1714 (x64).

11.05.2019    9684    Eret1k    22       

Выгрузка документа по условию 5

Статья Программист Нет файла v8 Бесплатно (free) Практика программирования Разработка

Что делать, если документы нужно выгружать не все подряд, а по какому-то фильтру: статусу, дате, набору условий... А что если он соответствовал этим условиям, а потом перестал? А если потом опять начал? Такие ситуации заставили попотеть не одного программиста.

25.04.2019    4728    m-rv    2       

Как прикрутить ГУИД к регистру сведений 23

Статья Программист Нет файла v8 Бесплатно (free) Практика программирования Перенос данных из 1C8 в 1C8 Разработка

... и немного теории обмена данными. В частности, разберем боль всех, кто пишет небанальные обмены данными: как набору записей регистра сведений назначить гуид и далее использовать его в обмене для идентификации этого набора.

16.04.2019    7245    m-rv    16       

О расширениях замолвите слово... 192

Статья Программист Стажер Нет файла v8 Бесплатно (free) Практика программирования Разработка

О чём стоит задуматься при принятии решения о создании расширения конфигурации…

07.04.2019    16213    ellavs    122       

Git-репозитории для 1С-кода (опыт использования при небольших проектах) 200

Статья Программист Стажер Нет файла v8 Windows Бесплатно (free) Практика программирования Разработка

Инструкции по взаимодействию с Git-репозиторием, которые писались для тех наших программистов, которые вообще никогда не работали с Git (руководства в духе "Как получить код из git-репозитория?", "Как отправить код в git-репозиторий")...

28.03.2019    12605    ellavs    83       

Трюки с внешними источниками данных 164

Статья Программист Нет файла v8 1cv8.cf Бесплатно (free) Практика программирования Разработка

Некоторые трюки для преодоления ограничений внешних источников данных.

14.03.2019    12713    YPermitin    52       

Возможности типовых шаблонов ограничения доступа на уровне записей (RLS) 162

Статья Программист Нет файла v8 v8::Права Бесплатно (free) Практика программирования БСП (Библиотека стандартных подсистем) Роли и права

Краткий обзор применения типовых шаблонов ограничения доступа на уровне записей в конфигурациях, созданных на базе БСП: #ПоЗначениям, #ПоНаборамЗначений, #ПоЗначениямРасширенный, #ПоЗначениямИНаборамРасширенный

03.02.2019    15287    ids79    9       

EnterpriseData – часть 2. Процесс выгрузки данных 127

Статья Программист Нет файла v8 v8::УФ Россия Бесплатно (free) Практика программирования Обмен через XML

Основные этапы выгрузки данных через ED, обработчики событий выгрузки, правила обработки данных, правила конвертации объектов, конвертация свойств первого и второго этапов, процедуры БСП, используемые при выгрузке данных, структура «КомпонентыОбмена».

26.12.2018    12595    ids79    27       

Новый подход к обмену данными EnterpriseData 202

Статья Программист Нет файла v8 v8::УФ Россия Бесплатно (free) Практика программирования Обмен через XML

Хочу предложить Вашему вниманию цикл статей, посвященных обмену данными через универсальный формат (EnterpriseData или ED).

14.12.2018    21210    ids79    72       

EnterpriseData - пример доработки правил конвертации без использования КД 3.0 в расширении конфигурации 118

Статья Программист Нет файла v8 v8::УФ БП3.0 УТ11 Россия Windows Бесплатно (free) Практика программирования Обмен через XML

В статье подробно описан реальный пример доработки обмена данными через EnterpriseData (универсальный формат обмена) между конфигурациями УТ 11.4 и Бухгалтерия 3.0

16.11.2018    18754    ids79    20       

Программное заполнение пользовательских параметров и отборов СКД 135

Статья Программист Нет файла v8 v8::СКД 1cv8.cf Бесплатно (free) Практика программирования

Публикация представляет из себя краткие примеры того, как можно заполнять параметры СКД программно так, чтобы все параметры и отборы были доступны в быстрых настройках и в обычных (типовых) настройках параметров и отборов СКД.

13.11.2018    19400    Unk92    18       

Автоматические и управляемые блокировки применительно к типовым конфигурациям 1С 125

Статья Программист Нет файла v8 v8::blocking 1cv8.cf Бесплатно (free) Математика и алгоритмы Практика программирования

Основные принципы работы с режимами автоматических и управляемых блокировок в 1С Предприятие 8. Теория и применение в типовых конфигурациях: БП, УТ, ЕРП

10.11.2018    20700    ids79    40       

Вспомогательные инструкции в коде 1С 104

Статья Программист Нет файла v8 1cv8.cf Бесплатно (free) Практика программирования

Помогаем редактору кода 1С помогать нам писать и анализировать код.

15.10.2018    20340    tormozit    100       

Произвольный код в фоновом режиме 164

Статья Программист Нет файла v8 1cv8.cf Бесплатно (free) Практика программирования

Задача: реализовать выполнение произвольного кода в фоновом режиме без изменения конфигурации, т.е. во внешней обработке.

03.09.2018    14479    nikita0832    41       

Основные понятия и механизмы оптимизации клиент-серверного взаимодействия в 1C 144

Статья Программист Нет файла v8 Россия Бесплатно (free) Математика и алгоритмы Практика программирования

У многих начинающих 1С программистов часто возникают вопросы про клиент-серверное взаимодействие в 1С и чтобы разобраться в непростых механизмах платформы, необходимо понять, что же такое контекст, для чего предназначены директивы компиляции, что представляют собой контекстные/внеконтекстные вызовы и как наиболее оптимально описывать прикладные задачи в модулях управляемых форм.

23.08.2018    21070    Rain88    42       

Повышаем эффективность разработки правил обмена 122

Статья Программист Нет файла v8 КД ОС Бесплатно (free) Практика программирования Перенос данных из 1C8 в 1C8

Как повысить скорость и качество разработки правил обмена? Как вести групповую разработку правил обмена? Как облегчить сопровождение правил обмена после передачи в эксплуатацию? Об этом и многом другом вы можете узнать из этой статьи.

25.06.2018    19202    olegtymko    43       

Введение в механизм представлений в ЗУП ред. 3 152

Статья Программист Нет файла v8 v8::СПР ЗУП3.x Бесплатно (free) Практика программирования

В нашей организации на первом же телефонном собеседовании на должность разработчика по ЗУП ред. 3 вас обязательно спросят о том, что такое "Представления".

04.06.2018    24209    xrrg    82       

Как сделать запрос на изменение данных 75

Статья Программист Нет файла v8 v8::Запросы 1cv8.cf Бесплатно (free) Практика программирования

В статье приведены особенности внутренней архитектуры и примеры работы с расширением языка запросов 1С.

01.06.2018    21089    m-rv    21       

Строим графы средствами 1С (без GraphViz) 42

Статья Программист Нет файла v8 Бесплатно (free) Практика программирования

Множество статей на Инфостарте описывают, как работать с компонентой GraphViz, чтобы построить ориентированный граф. Но практически нет материалов, как работать с такими графами средствами 1С. Сегодня я расскажу, как красиво строить графы с минимальным пересечением. Нам этот метод пригодился для отрисовки алгоритмов в БИТ.Финансе, т.к. типовой механизм не устраивал. Еще это может быть полезно для визуализации различных зависимостей: расчета себестоимости, графы аффилированности компаний и т.д. Надеюсь, эта статья поможет сделать мир 1С красивее и гармоничней:) Итак, поехали...

23.05.2018    16862    slozhenikin_com    19       

Распределение расходов пропорционально продажам 9

Статья Программист Пользователь Нет файла v8 v8::ОУ УТ10 УУ Финансовый учет и бюджетирование (FRP) Учет доходов и расходов Бесплатно (free) Практика программирования

Финансовая модель. Распределение административных расходов по подразделениям пропорционально продажам за месяц. Дополнительные реквизиты против бизнес-процессов!

13.05.2018    11258    Rustig    9       

Просмотр временных таблиц запроса в отладчике без изменения кода 126

Статья Программист Нет файла v8 v8::Запросы 1cv8.cf Бесплатно (free) Практика программирования

Данный способ можно использовать для просмотра содержимого временных таблиц запросов (менеджеров временных таблиц) без внесения изменений в код.

24.04.2018    24170    avfed@rambler.ru    19       

Минимализмы 3 350

Статья Программист Нет файла v8 Бесплатно (free) Практика программирования Универсальные функции

Очередная серия "минимализмов" [http://infostart.ru/public/306536/, https://infostart.ru/public/460935/]. Также, как и в предыдущих статьях, здесь приведена подборка коротких оригинальных авторских решений некоторых задач. Ранее эти решения были разбросаны по моим комментариям к чужим публикациям.

19.02.2018    35404    ildarovich    44       

Этюды по программированию. Взаимодействие с Microsoft Word 108

Статья Программист Нет файла v8 Бесплатно (free) Практика программирования

Часто приходится заниматься созданием сложных документов Word с таблицами, вложенными фрагментами, хитрым оформлением и прочими радостями жизни. Это - попытка как-то структурировать полученный опыт, чтобы не приходилось перерывать ворох старых обработок в поисках крупиц истины. Надеюсь, эта статья будет полезна и Вам.

11.12.2017    25750    milkers    23       

Метод формирования движений в типовых регистрах нетиповыми регистраторами 31

Статья Программист Нет файла v8 1cv8.cf Бесплатно (free) Практика программирования

Вариант решения задач с проведением по типовым регистрам нетиповыми регистраторами. Зачем - чтобы при сравнении конфигурации не обращать внимание на свойства регистров и исключить вероятность допущения горькой оплошности при обновлении информационных баз, заменив типы регистраторов основной конфигурации типами конфигурации поставщика. Для программных продуктов, имеющих в своем составе метаданных документ "Корректировка регистров"("Корректировка записей регистров").

05.12.2017    21233    itriot11    34       

1С: Конвертация данных 3. Инструкции и примеры. EnterpriseData (универсальный формат обмена) 720

Статья Программист Нет файла v8 КД Бесплатно (free) Перенос данных из 1C8 в 1C8 Практика программирования Обмен через XML

Что такое КД3? Как начать использовать? Полезные дополнения к документации. Что нужно исправить в типовых обработках и конфигурации. Как изменить правила обмена не снимая конфигурацию с поддержки. Как отлаживать правила обмена?

19.11.2017    137035    MaxS    251       

Заполнение данных по ИНН контрагента с помощью альтернативного сервиса огрн.онлайн 131

Статья Программист Нет файла v8 Бесплатно (free) Практика программирования

Код для заполнения данных по ИНН контрагента из ЕГРЮЛ с сайта огрн.онлайн.

01.11.2017    22586    slava_1c    49       

Программные перечисления, ч.2: приемы кэширования при разработке 66

Статья Программист Нет файла v8 Бесплатно (free) Практика программирования

Все знают, что такое кэш, и зачем он нужен. Но в 1С разработчик обычно использует кэширование только на уровне конфигурации, а в какой-нибудь обработке скорее ломает голову над запросом - как получить все данные за один заход... Хочется рассказать о том, как можно добиться хороших результатов с стратегией "разделяй и властвуй".

30.10.2017    20959    unichkin    17       

Разбираемся с настройками компоновки данных 159

Статья Программист Нет файла v8 v8::СКД 1cv8.cf Бесплатно (free) Практика программирования

Краткая шпаргалка по программной работе с настройками СКД

29.10.2017    23928    json    9       

Работа с Excel 287

Статья Программист Нет файла v8 Бесплатно (free) Практика программирования Загрузка и выгрузка в Excel

Собрал различные полезности для работы с Excel из 1С. Иногда приходится форматировать документ Excel программно из 1С. Так вот, чтобы не искать постоянно на просторах интернета как сделать левое выравнивание в ячейке Excel из 1С и т.п. решил опубликовать это...

23.10.2017    24483    arakelyan    39       

Добавление команд печати в конфигурациях на БСП 2.4.3 (в частности, в самописных документах в Бухгалтерии 3.0 после релиза 3.0.52.35) 143

Статья Программист Нет файла v8 v8::БУ БП3.0 Россия Бесплатно (free) Печатные формы документов Практика программирования БСП (Библиотека стандартных подсистем)

В статье https://infostart.ru/public/237013/ пользователя nick max рассматривался список действий для подключения команд печати в Бухгалтерии 3.0, работающей на БСП 2.3.6. В новом релизе Бухгалтерии 3.0.52.35 от 15.09.2017г. стала использоваться БСП 2.4.3, из-за чего произошли изменения в процедурах общих модулей, связанных с механизмом печати, и в процедурах их вызова в формах документов и в формах списков. Рассмотрим их.

18.09.2017    46567    bugtester    43       

Отказ от работы с временными файлами при работе с двоичными данными или Потоки как простая замена ADODB.Stream и временным файлам 127

Статья Программист Нет файла v8 Россия Бесплатно (free) Практика программирования

В платформе начиная с версии 3.8.9 (как я понял по документации) появился расширенный функционал средств работы с двоичными данными. Если раньше простой и очевидный способ преобразования данных строился на использовании временных файлов, то теперь благодаря новым средствам можно уйти от их использования.

12.09.2017    18136    vardeg    31